Overview
| Comment: | s_expressions-parsers: new package containing an event-base S-expression parser |
|---|---|
| Timelines: | family | ancestors | descendants | both | trunk |
| Files: | files | file ages | folders |
| SHA1: |
dffc102c0d432e03550a0d62da175645 |
| User & Date: | nat on 2014-01-10 22:49:00 |
| Other Links: | manifest | tags |
Context
|
2014-01-11
| ||
| 11:40 | s_expressions-printers: new procedure Transfer running a Descriptor into a Printer check-in: f16c5302d7 user: nat tags: trunk | |
|
2014-01-10
| ||
| 22:49 | s_expressions-parsers: new package containing an event-base S-expression parser check-in: dffc102c0d user: nat tags: trunk | |
|
2014-01-09
| ||
| 22:19 | s_expressions-printers-tests: fully-covering test suite for canonical atom printer check-in: 08a213ab1f user: nat tags: trunk | |
Changes
Added src/natools-s_expressions-parsers.adb version [0ce9683aff].
> > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > | 1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359 360 361 362 363 364 365 366 367 368 369 370 371 372 373 374 375 376 377 378 379 380 381 382 383 384 385 386 387 388 389 390 391 392 393 394 395 396 397 398 399 400 401 402 403 404 405 406 407 408 409 410 411 412 413 414 415 416 417 418 419 420 421 422 423 424 425 426 427 428 429 430 431 432 433 434 435 436 437 438 439 440 441 442 443 444 445 446 447 448 449 450 451 452 453 454 455 456 457 458 459 460 461 462 463 464 465 466 467 468 469 470 471 472 473 474 475 476 477 478 479 480 481 482 483 484 485 486 487 488 489 490 |
------------------------------------------------------------------------------
-- Copyright (c) 2013-2014, Natacha Porté --
-- --
-- Permission to use, copy, modify, and distribute this software for any --
-- purpose with or without fee is hereby granted, provided that the above --
-- copyright notice and this permission notice appear in all copies. --
-- --
-- THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES --
-- WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF --
-- MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR --
-- ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES --
-- WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN --
-- ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF --
-- OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE. --
------------------------------------------------------------------------------
with Natools.S_Expressions.Encodings;
package body Natools.S_Expressions.Parsers is
----------------------
-- Parser Interface --
----------------------
function Current_Event (P : in Parser) return Events.Event is
begin
return P.Latest;
end Current_Event;
function Current_Atom (P : in Parser) return Atom is
begin
if P.Latest /= Events.Add_Atom then
raise Program_Error;
end if;
return P.Buffer.Query;
end Current_Atom;
function Current_Level (P : in Parser) return Natural is
begin
return P.Level;
end Current_Level;
procedure Query_Atom
(P : in Parser;
Process : not null access procedure (Data : in Atom)) is
begin
if P.Latest /= Events.Add_Atom then
raise Program_Error;
end if;
P.Buffer.Query (Process);
end Query_Atom;
procedure Read_Atom
(P : in Parser;
Data : out Atom;
Length : out Count) is
begin
if P.Latest /= Events.Add_Atom then
raise Program_Error;
end if;
P.Buffer.Query (Data, Length);
end Read_Atom;
procedure Next_Event
(P : in out Parser;
Input : not null access Ada.Streams.Root_Stream_Type'Class)
is
O : Octet;
Item : Ada.Streams.Stream_Element_Array (1 .. 1);
Last : Ada.Streams.Stream_Element_Offset;
begin
P.Latest := Events.Error;
loop
-- Process pending events
if P.Pending /= Events.End_Of_Input then
P.Latest := P.Pending;
P.Pending := Events.End_Of_Input;
case P.Latest is
when Events.Open_List =>
P.Level := P.Level + 1;
when Events.Close_List =>
if P.Level > 0 then
P.Level := P.Level - 1;
end if;
when others => null;
end case;
exit;
end if;
-- Read a single octet from source
if P.Override_Pos < P.Override.Length then
P.Override_Pos := P.Override_Pos + 1;
O := P.Override.Element (P.Override_Pos);
if P.Override_Pos >= P.Override.Length then
P.Override.Hard_Reset;
P.Override_Pos := 0;
end if;
else
Input.Read (Item, Last);
if Last not in Item'Range then
P.Latest := Events.End_Of_Input;
exit;
end if;
O := Item (Last);
end if;
-- Process octet
case P.Internal.State is
when Waiting =>
P.Buffer.Soft_Reset;
case O is
when 0 | Encodings.Space | Encodings.HT
| Encodings.CR | Encodings.LF
| Encodings.VT | Encodings.FF =>
null;
when Encodings.List_Begin =>
P.Latest := Events.Open_List;
P.Level := P.Level + 1;
when Encodings.List_End =>
P.Latest := Events.Close_List;
if P.Level > 0 then
P.Level := P.Level - 1;
end if;
when Encodings.Base64_Atom_Begin =>
P.Internal := (State => Base64_Atom,
Chunk => (Data => <>, Length => 0));
when Encodings.Base64_Expr_Begin =>
P.Internal := (State => Base64_Expr,
Chunk => (Data => <>, Length => 0));
when Encodings.Hex_Atom_Begin =>
P.Internal := (State => Hex_Atom,
Nibble_Buffer => 0);
when Encodings.Quoted_Atom_Begin =>
P.Internal := (State => Quoted_Atom,
Escape => (Data => <>, Length => 0));
when Encodings.Digit_0 .. Encodings.Digit_9 =>
P.Internal := (State => Number);
Atom_Buffers.Append (P.Buffer, O);
when others =>
P.Internal := (State => Token);
Atom_Buffers.Append (P.Buffer, O);
end case;
when Base64_Atom | Base64_Expr =>
if Encodings.Is_Base64_Digit (O) then
P.Internal.Chunk.Data (P.Internal.Chunk.Length) := O;
P.Internal.Chunk.Length := P.Internal.Chunk.Length + 1;
if P.Internal.Chunk.Length = 4 then
P.Buffer.Append
(Encodings.Decode_Base64 (P.Internal.Chunk.Data));
P.Internal.Chunk.Length := 0;
end if;
elsif (O = Encodings.Base64_Atom_End
and P.Internal.State = Base64_Atom)
or (O = Encodings.Base64_Expr_End
and P.Internal.State = Base64_Expr)
then
P.Buffer.Append
(Encodings.Decode_Base64 (P.Internal.Chunk.Data
(0 .. P.Internal.Chunk.Length - 1)));
if P.Internal.State = Base64_Atom then
P.Latest := Events.Add_Atom;
else
P.Override.Append (P.Buffer.Query);
P.Buffer.Soft_Reset;
end if;
P.Internal := (State => Waiting);
end if;
when Hex_Atom =>
if Encodings.Is_Hex_Digit (O) then
if Encodings.Is_Hex_Digit (P.Internal.Nibble_Buffer) then
P.Buffer.Append
(Encodings.Decode_Hex (P.Internal.Nibble_Buffer, O));
P.Internal.Nibble_Buffer := 0;
else
P.Internal.Nibble_Buffer := O;
end if;
elsif O = Encodings.Hex_Atom_End then
P.Latest := Events.Add_Atom;
P.Internal := (State => Waiting);
end if;
when Number =>
case O is
when Encodings.Digit_0 .. Encodings.Digit_9 =>
P.Buffer.Append (O);
when Encodings.Verbatim_Begin =>
P.Internal := (State => Verbatim_Atom, Size => 0);
for I in 1 .. P.Buffer.Length loop
P.Internal.Size := P.Internal.Size * 10
+ Count (P.Buffer.Element (I) - Encodings.Digit_0);
end loop;
P.Buffer.Soft_Reset;
if P.Internal.Size = 0 then
P.Latest := Events.Add_Atom;
P.Internal := (State => Waiting);
else
P.Buffer.Preallocate (P.Internal.Size);
end if;
when 0 | Encodings.Space | Encodings.HT
| Encodings.CR | Encodings.LF
| Encodings.VT | Encodings.FF =>
P.Latest := Events.Add_Atom;
P.Internal := (State => Waiting);
when Encodings.List_Begin =>
P.Internal := (State => Waiting);
P.Pending := Events.Open_List;
P.Latest := Events.Add_Atom;
when Encodings.List_End =>
P.Internal := (State => Waiting);
P.Pending := Events.Close_List;
P.Latest := Events.Add_Atom;
when Encodings.Base64_Atom_Begin =>
P.Internal := (State => Base64_Atom,
Chunk => (Data => <>, Length => 0));
P.Buffer.Soft_Reset;
when Encodings.Base64_Expr_Begin =>
P.Internal := (State => Base64_Expr,
Chunk => (Data => <>, Length => 0));
P.Buffer.Soft_Reset;
when Encodings.Hex_Atom_Begin =>
P.Internal := (State => Hex_Atom,
Nibble_Buffer => 0);
P.Buffer.Soft_Reset;
when Encodings.Quoted_Atom_Begin =>
P.Internal := (State => Quoted_Atom,
Escape => (Data => <>, Length => 0));
P.Buffer.Soft_Reset;
when others =>
P.Buffer.Append (O);
P.Internal := (State => Token);
end case;
when Quoted_Atom =>
case P.Internal.Escape.Length is
when 0 =>
case O is
when Encodings.Escape =>
P.Internal.Escape.Data (0) := O;
P.Internal.Escape.Length := 1;
when Encodings.Quoted_Atom_End =>
P.Internal := (State => Waiting);
P.Latest := Events.Add_Atom;
when others =>
P.Buffer.Append (O);
end case;
when 1 =>
case O is
when Character'Pos ('b') =>
P.Buffer.Append (8);
P.Internal.Escape.Length := 0;
when Character'Pos ('t') =>
P.Buffer.Append (9);
P.Internal.Escape.Length := 0;
when Character'Pos ('n') =>
P.Buffer.Append (10);
P.Internal.Escape.Length := 0;
when Character'Pos ('v') =>
P.Buffer.Append (11);
P.Internal.Escape.Length := 0;
when Character'Pos ('f') =>
P.Buffer.Append (12);
P.Internal.Escape.Length := 0;
when Character'Pos ('r') =>
P.Buffer.Append (13);
P.Internal.Escape.Length := 0;
when Character'Pos (''') | Encodings.Escape
| Encodings.Quoted_Atom_End =>
P.Buffer.Append (O);
P.Internal.Escape.Length := 0;
when Encodings.Digit_0 .. Encodings.Digit_0 + 3
| Character'Pos ('x')
| Encodings.CR | Encodings.LF =>
P.Internal.Escape.Data (1) := O;
P.Internal.Escape.Length := 2;
when others =>
P.Buffer.Append
((1 => P.Internal.Escape.Data (0), 2 => O));
P.Internal.Escape.Length := 0;
end case;
when 2 =>
if (P.Internal.Escape.Data (1) in Encodings.Digit_0
.. Encodings.Digit_0 + 3
and O in Encodings.Digit_0 .. Encodings.Digit_0 + 7)
or (P.Internal.Escape.Data (1) = Character'Pos ('x')
and then Encodings.Is_Hex_Digit (O))
then
P.Internal.Escape.Data (2) := O;
P.Internal.Escape.Length := 3;
elsif P.Internal.Escape.Data (1) = Encodings.CR
or P.Internal.Escape.Data (1) = Encodings.LF
then
P.Internal.Escape.Length := 0;
if not ((O = Encodings.CR or O = Encodings.LF)
and O /= P.Internal.Escape.Data (1))
then
P.Buffer.Append (O);
end if;
else
P.Buffer.Append
((P.Internal.Escape.Data (0),
P.Internal.Escape.Data (1),
O));
P.Internal.Escape.Length := 0;
end if;
when 3 =>
if P.Internal.Escape.Data (1) = Character'Pos ('x') then
if Encodings.Is_Hex_Digit (O) then
P.Buffer.Append
(Encodings.Decode_Hex (P.Internal.Escape.Data (2),
O));
else
P.Buffer.Append
((P.Internal.Escape.Data (0),
P.Internal.Escape.Data (1),
P.Internal.Escape.Data (2),
O));
end if;
else
pragma Assert (P.Internal.Escape.Data (1)
in Encodings.Digit_0 .. Encodings.Digit_0 + 3);
if O in Encodings.Digit_0 .. Encodings.Digit_0 + 7 then
Atom_Buffers.Append
(P.Buffer,
(P.Internal.Escape.Data (1) - Encodings.Digit_0)
* 2**6 +
(P.Internal.Escape.Data (2) - Encodings.Digit_0)
* 2**3 +
(O - Encodings.Digit_0));
else
P.Buffer.Append
((P.Internal.Escape.Data (0),
P.Internal.Escape.Data (1),
P.Internal.Escape.Data (2),
O));
end if;
end if;
P.Internal.Escape.Length := 0;
when 4 =>
raise Program_Error;
end case;
when Token =>
case O is
when 0 | Encodings.Space | Encodings.HT
| Encodings.CR | Encodings.LF
| Encodings.VT | Encodings.FF =>
P.Internal := (State => Waiting);
P.Latest := Events.Add_Atom;
when Encodings.List_Begin =>
P.Internal := (State => Waiting);
P.Pending := Events.Open_List;
P.Latest := Events.Add_Atom;
when Encodings.List_End =>
P.Internal := (State => Waiting);
P.Pending := Events.Close_List;
P.Latest := Events.Add_Atom;
when others =>
P.Buffer.Append (O);
end case;
when Verbatim_Atom =>
P.Buffer.Append (O);
pragma Assert (P.Buffer.Length <= P.Internal.Size);
if P.Buffer.Length = P.Internal.Size then
P.Internal := (State => Waiting);
P.Latest := Events.Add_Atom;
end if;
end case;
exit when P.Latest /= Events.Error;
end loop;
end Next_Event;
-------------------------
-- Subparser functions --
-------------------------
function Current_Event (P : in Subparser) return Events.Event is
begin
if P.Terminated then
return Events.End_Of_Input;
else
return Current_Event (P.Backend.all);
end if;
end Current_Event;
function Current_Atom (P : in Subparser) return Atom is
begin
if P.Terminated then
raise Constraint_Error;
else
return Current_Atom (P.Backend.all);
end if;
end Current_Atom;
function Current_Level (P : in Subparser) return Natural is
begin
if P.Terminated then
return P.Base_Level;
else
return Current_Level (P.Backend.all);
end if;
end Current_Level;
procedure Query_Atom
(P : in Subparser;
Process : not null access procedure (Data : in Atom)) is
begin
if P.Terminated then
raise Constraint_Error;
else
Query_Atom (P.Backend.all, Process);
end if;
end Query_Atom;
procedure Read_Atom
(P : in Subparser;
Data : out Atom;
Length : out Count) is
begin
if P.Terminated then
raise Constraint_Error;
else
Read_Atom (P.Backend.all, Data, Length);
end if;
end Read_Atom;
procedure Next (P : in out Subparser; Event : out Events.Event) is
begin
if P.Terminated then
raise Constraint_Error;
end if;
if not P.Initialized then
P.Base_Level := Current_Level (P.Backend.all);
P.Initialized := True;
end if;
Next_Event (P.Backend.all, P.Input);
Event := Current_Event (P.Backend.all);
if Event = Events.Close_List
and then Current_Level (P.Backend.all) < P.Base_Level
then
P.Terminated := True;
Event := Events.End_Of_Input;
end if;
end Next;
procedure Finish (P : in out Subparser) is
Event : Events.Event := Current_Event (P);
begin
while Event /= Events.Error and Event /= Events.End_Of_Input loop
Next (P, Event);
end loop;
end Finish;
end Natools.S_Expressions.Parsers;
|
Added src/natools-s_expressions-parsers.ads version [089b8c8cea].
> > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > > | 1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 |
------------------------------------------------------------------------------
-- Copyright (c) 2013-2014, Natacha Porté --
-- --
-- Permission to use, copy, modify, and distribute this software for any --
-- purpose with or without fee is hereby granted, provided that the above --
-- copyright notice and this permission notice appear in all copies. --
-- --
-- THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES --
-- WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF --
-- MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR --
-- ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES --
-- WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN --
-- ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF --
-- OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE. --
------------------------------------------------------------------------------
------------------------------------------------------------------------------
-- Natools.S_Expressions.Parsers implements an event-based S-expression --
-- parser that reads from an input stream. --
-- --
-- Subparser objects wrap together Parser and input Stream, exposing a --
-- Descriptor interface. A subparser is constrained to its initial nesting --
-- level, and reports end-of-input instead of reaching lower. --
------------------------------------------------------------------------------
with Ada.Streams;
with Natools.S_Expressions.Atom_Buffers;
package Natools.S_Expressions.Parsers is
pragma Preelaborate (Natools.S_Expressions.Parsers);
type Parser is tagged private;
function Current_Event (P : in Parser) return Events.Event;
function Current_Atom (P : in Parser) return Atom;
function Current_Level (P : in Parser) return Natural;
procedure Query_Atom
(P : in Parser;
Process : not null access procedure (Data : in Atom));
procedure Read_Atom
(P : in Parser;
Data : out Atom;
Length : out Count);
procedure Next_Event
(P : in out Parser;
Input : not null access Ada.Streams.Root_Stream_Type'Class);
type Subparser
(Backend : access Parser;
Input : access Ada.Streams.Root_Stream_Type'Class)
is new Descriptor with private;
overriding function Current_Event (P : in Subparser) return Events.Event;
overriding function Current_Atom (P : in Subparser) return Atom;
overriding function Current_Level (P : in Subparser) return Natural;
overriding procedure Query_Atom
(P : in Subparser;
Process : not null access procedure (Data : in Atom));
overriding procedure Read_Atom
(P : in Subparser;
Data : out Atom;
Length : out Count);
overriding procedure Next (P : in out Subparser; Event : out Events.Event);
procedure Finish (P : in out Subparser);
-- Read enough data to exhaust intial nesting level
private
type Internal_State is
(Waiting, -- waiting for a marker
Base64_Atom, -- reading an atom encoded in base 64
Base64_Expr, -- reading an expression encoded in base 64
Hex_Atom, -- reading an atom encoded in hexadecimal
Number, -- reading a number that can either be a verbatim
-- length prefix or an extended token
Quoted_Atom, -- reading an atom encoded in a C-like quoted string
Token, -- reading a token atom
Verbatim_Atom); -- reading a verbatim atom
subtype Read_Buffer_Count is Count range 0 .. 4;
type Read_Buffer is record
Data : Atom (0 .. 3);
Length : Read_Buffer_Count;
end record;
type State_Data (State : Internal_State := Waiting) is record
case State is
when Waiting | Number | Token =>
null;
when Base64_Atom | Base64_Expr =>
Chunk : Read_Buffer;
when Hex_Atom =>
Nibble_Buffer : Octet;
when Quoted_Atom =>
Escape : Read_Buffer;
when Verbatim_Atom =>
Size : Count;
end case;
end record;
type Parser is tagged record
Internal : State_Data;
Pending : Events.Event := Events.End_Of_Input;
Override : Atom_Buffers.Atom_Buffer;
Override_Pos : Count := 0;
Latest : Events.Event := Events.Error;
Buffer : Atom_Buffers.Atom_Buffer;
Level : Natural := 0;
end record;
type Subparser
(Backend : access Parser;
Input : access Ada.Streams.Root_Stream_Type'Class)
is new Descriptor with record
Base_Level : Natural := 0;
Initialized : Boolean := False;
Terminated : Boolean := False;
end record;
end Natools.S_Expressions.Parsers;
|